Shranjevanje datoteke v drug format

[Iztok75]

Pozdravljeni,

zanima me ali je in kako mogoče shranit xls datoteko kot neke vrste cvs datoteko, samo da bi med vsako celico ki jo zapiše ločil z "," ali ";"?

Izgled:

"celicaA1","celicaB1","celicaC1"....
"celicaA2","celicaB2","celicaC2"....
...
...

[kljuka13]

Kaj pa je sploh CVS datoteka ?

[admin]

Excel sam zase tega ne zna, niti nima opcije, ki v bi CSV datoteki elemente ločila z narekovaji. Za rešitev je potrebno napisati majhen makro.

[Iztok75]

Našel :

Sub QuoteCommaExport()
Dim DestFile As String
Dim FileNum As Integer
Dim ColumnCount As Integer
Dim RowCount As Integer

' Prompt user for destination file name.
DestFile = InputBox("Enter the destination filename" & _
Chr(10) & "(with complete path and extension):", _
"Quote-Comma Exporter")
' Obtain next free file handle number.
FileNum = FreeFile()

' Turn error checking off.
On Error Resume Next

' Attempt to open destination file for output.
Open DestFile For Output As #FileNum
' If an error occurs report it and end.
If Err <> 0 Then
MsgBox "Cannot open filename " & DestFile
End
End If

' Turn error checking on.
On Error GoTo 0

' Loop for each row in selection.
For RowCount = 1 To Selection.Rows.Count
' Loop for each column in selection.
For ColumnCount = 1 To Selection.Columns.Count

' Write current cell's text to file with quotation marks.
Print #FileNum, """" & Selection.Cells(RowCount, _
ColumnCount).Text & """";
' Check if cell is in last column.
If ColumnCount = Selection.Columns.Count Then
' If so, then write a blank line.
Print #FileNum,
Else
' Otherwise, write a comma.
Print #FileNum, ",";
End If
' Start next iteration of ColumnCount loop.
Next ColumnCount
' Start next iteration of RowCount loop.
Next RowCount

' Close destination file.
Close #FileNum
End Sub


Orig.stran: http://msdn2.microsoft.com/en-us/library/aa203726.aspx

Hvala za trud,