IF FUNKCIJA

[BD]

Pozdravljeni,
v bazi podatkov imam v stolpcu A preračunavanje različnih količin(stolpec B so em) iz stolpca C v enotno količino (npr. iz tone/stolpec C/ v paleto/stolpec A/), rada bi dodala še iz kg v paleto in kosi v paleto vendar to ni razmerje 1:1 (kot je to sedaj iz t v paleto).
katero funkcijo bi dodala da bi mi izpisovalo npr. če je 10.000kg = 8 palet, 1500 kosov = 17 palet, itd??

sedaj to zgleda tako:
A STOLPEC=12, B STOPEC= T, C STOLPEC=12
IN FUNKCIJA PA:
LOGICAL TEST:=IF(OR(B14="T";B14="PAL";B14="MT";);A14;0)
VALUE IF TRUE:A14
VALUE IF FALSE:0

[admin]

Ups, tole sem pa povsem spregledal. Če je še aktualno, prosim podrobneje razložite problem, ker ga ne rezumem najbolje. Priporočam, da napišate par primerov.

[BD]

Torej, trenutno imam dva stolpca v tabeli A in B. V stolpcu A se izpisujejo količine v tonah, kg, kosih,ipd. V stolpcu B pa bi rada z funkcijo da mi količino v A stolpcu pretvori v poenoteno količino to je tona. Naprimer če je v A 10t = v B 10t, če je v A 10000kg = v B 10t, če je v A 5 kosov = v B 7t,... Količine so lahko fiksne saj gre za povprečno pretvorbo. Upam da sem bila zdaj kaj bolj jasna....?
lp

[admin]

Ok, sedaj je stvar skoraj povsem jasna in tudi rešitev je dokaj trivialna; povedati mi morate samo še, na kakšen način bova ugotovila v kateri količini je neka vrednost v stolpcu A zapisana. Ali so v stolpcu A količine pisane kot 10T in podobno? V tem primeru so torej zapisane kot nizi znakov in ne kot številke; je res?

[BD]

Podatke uvažam iz drugega programa in potem urejam bazo naprej... v stolpcu A mi izpiše številke (ki pa pomenijo T, KG, KOSE in PALETE), tudi v stolpec B bi rada da mi pretvori v številke (ampak v poenoteno v T, zaradi končnega seštevka in nadaljne obdelave).
Bi šlo tako?

[admin]

Ok, Najprej porebujete tabelo, kjer bost imeli zapisane pretvorbe iz poljubne količine v tone; npr:

Koda: Izberi vse

T      1
KG     0,001
PAL    0,01

Recimo, da se ta tabela nahaja na listu2 od A1 do B3. Sedaj pa k rešitvi vašega problema, ki ga bova rešila v 5 korakih oz. v 5 stolpcih. To bova naredila zato, da mi boste lahko sledili. Še vedno pa boste lahko vseskupaj zapisali kot eno ZELO veliko funkcijo. Če vam jo napišem jaz sploh ne boste razumeli kaj pomeni . Torej greva po korakih.

• V stolpcu B bova najprej ugotovila, kje je presledek, ki loči številke od količin

  Koda: Izberi vse

  =FIND(" "; A2)

• V stolpcu C bova iz stolpca a izluščila količino

  Koda: Izberi vse

  =TRIM(MID(A2;B2+1;4))

• V stolpcu D bova preko količine iz stolpca C in tabele pretvorb dobila ustrezen pretvorbni faktor

  Koda: Izberi vse

  =VLOOKUP(C2;List2!$A$1:$B$3;2;FALSE)

• V stolpcu E bova iz stolpca a izluščila vrednost

  Koda: Izberi vse

  =VALUE(LEFT(A2;B2-1))

• V stolpcu F bova pomnožila vrednost s fakorjem pretvorbe

  Koda: Izberi vse

  =E6*D6

  - TO JE REZULTAT V TONAH

Primer:

Koda: Izberi vse

  A    | B |  C  |   D   |  E  |   F 
123 kg | 4 | kg  | 0,001 | 123 | 0,123
10 t   | 3 | t   |     1 |  10 |    10
7 pal  | 2 | pal |  0,01 |   7 |  0,07

Pa še vse skupaj v eni formuli (primer za celico B9)

Koda: Izberi vse

=VLOOKUP(TRIM(MID(A9;FIND(" "; A9)+1;4));List2!$A$1:$B$3;2;FALSE)*VALUE(LEFT(A9;FIND(" "; A9)-1))

[BD]

uspelo ! malo manjša formula je ratala, ker sem se prej očitno malo slabo izrazila saj sem se mi uvoženi podatki že sami razdelijo na stolpec A=količine, stolpec B=em. No kakorkoli, najlepša hvala za vašo pomoč in lep pozdrav!